~ start
if GameState.playerIsDeaf:
	Bob: BONJOUR L'AMI [if GameState.hasChosenNotToMakeChoices]QUI N'AIME PAS FAIRE DE CHOIX[/if]! JE PARLE FORT POUR QUE TU ENTENDES OKAY?
else:
	Bob: Bonjour l'ami [if GameState.hasChosenNotToMakeChoices]qui n'aime pas faire de choix[/if]
if GameState.hasCompletedBobDialogue == true
	Bob: On s'est déjà tout dit, tchö => END
if GameState.isUsingTouch == false
	Bob: Je vois que t'es venu au clavier!
else:
	Bob: Je vois que t'es venu avec tes petits doigts!
% Bob: Qu'estce qui t'amène sur chaussette sale??
% 
	Bob: Est-ce que tu connais les contrôles du jeu?
	Bob: En vrai, si tu est venu jusqu'à moi et qu'on parle, je suppose que oui!
Bob: Est-ce que tu veux faire des choix?
~ choices
- Non merci [if GameState.hasChosenNotToMakeChoices == false]
	Bob: Petit chenapan! Tu viens d'en faire un, tu m'a l'air d'un sacré loustic, allez file avant que je t'oublies
	set GameState.hasChosenNotToMakeChoices = true
- Oui! [if GameState.hasChosenToMakeChoices == false]
	Bob: Je savais que tu choisirai quelque chose. Bravo pour ce choix conséquent qui aura des conséquences conséquentes.
	set GameState.hasChosenToMakeChoices = true
- Pardon? J'ai mal entendu [if GameState.playerIsDeaf == false]
	set GameState.playerIsDeaf = true
	=> start
- Oula! je'm'casse! => after_choices
=> choices
~ after_choices
if GameState.hasChosenToMakeChoices == true and GameState.hasChosenNotToMakeChoices == true
	=> next_dialogue
=> END

~ next_dialogue
Bob: Attends, avant que tu partes, j'aimerais te parler un peu
Bob: Ici c'est un peu vide pour le moment, c'est normal, c'est en construction.
Bob: Mais ne prends pas peur, explore un peu et reviens dans quelques temps, il y aura peut être même un peu de gameplay!
set GameState.hasCompletedBobDialogue = true
=> END